FindExclude

local CR = esc(?+\r+, ?+\+)
local Quote = esc(?+"+, ?+\+)
local hwnd = win.handle("c=TTOTAL_CMD")
;"\ini\" - subdirectory of scripts created manually
local Settings = scriptfolder ++ "\ini\FindExclude.ini"
local Files = ini.enum_keys(Settings, "Files")
local FileCounter = line(Files, 0)
local Dirs = ini.enum_keys(Settings, "Dirs")
local DirCounter = line(Dirs, 0)
local Result, Str, i, Temp

FMask = vec.create(FileCounter)
if(FMask == 0) do
	messagebox("ok error", "Vector not created", "VEC plugin error #1")
	quit
endif

DMask = vec.create(DirCounter)
if(DMask == 0) do
	messagebox("ok error", "Vector not created", "VEC plugin error #2")
	quit
endif

for(i = 1; i <= FileCounter; i++)
	Temp = line(Files, i)
	Str = ini.get(Settings, "Files", Temp)
	FMask[i - 1] = Str
	Result = Result ++ "Files: " ++ Quote ++ Temp ++ Quote ++ ", mask: " ++ Quote
	Result = Result ++ Str ++ Quote ++ CR
endfor

for(i = 1; i <= DirCounter; i++)
	Temp = line(Dirs, i)
	Str = ini.get(Settings, "Dirs", Temp)
	DMask[i - 1] = Str
	Result = Result ++ "Directories: " ++ Quote ++ Temp ++ Quote ++ ", path: " ++ Quote
	Result = Result ++ Str ++ Quote ++ CR
endfor

pickstring(Result, "Pick Item(s) to Exclude", 1)
DirCounter = word(_pickedline_, 0)

if(not _pickedline_)
	quit

Files = ifelse(ini.get(Settings, "Options", "Asterisk"), "*.* |", "|")
Dirs = ""

for(i = 1; i <= DirCounter; i++)
	Temp = word(_pickedline_, i)
	if(Temp <= FileCounter) do
		Files = Files ++ " " ++ FMask[Temp - 1]
	else
		Dirs = Dirs ++ " " ++ DMask[Temp - FileCounter - 1] ++ "\"
	endif
endfor

vec.destroy(FMask)
vec.destroy(DMask)

Str = Files ++ Dirs
win.postmessage(hwnd, 0x400+51, 501, 0)
Temp = ini.get(Settings, "Options", "FileDir")
wait.for(activewindow("c=TFindFile"))
Files = win.handle("c=TFindFile")

if(Temp != 2) do
	keys +{tab}{right}{tab 4}{space}{tab 2}{space}
	if(Temp)
		keys {space}

	keys {tab 6}{left}
endif

Dirs = childwin.handle(Files, 23)
win.settext(Dirs, Str)

for(childwin.gettext(Dirs) != Str)
	win.settext(Dirs, Str)
endfor

if(ini.get(Settings, "Options", "StartNow"))
	keys {enter}