BatchMD

Название BatchMD
Имя файла (*.txt) BatchMD.txt
Описание Создает множество директорий
Автор Вахмурка
Параметры "%p", Перед, От, До, После
Вызываемые плагины win, file
Иконка
Версия 1.0
Дата обновления 21.08.2008
args Path, Before, Start, End, After
local hwnd = win.handle("c=TTOTAL_CMD")
local Temp, i, Str

if(Start >= End) do
	Temp = "Starting value of the counter (" ++ Start ++ ") must be less than "
	Temp = Temp ++ "ending value (" ++ End ++ ")"
	messagebox("ok error", Temp, "BatchMD Script")
	quit
endif

if(Start < 0 || End < 0) do
	messagebox("ok error", "Counter must be non-negative value", "BatchMD Script")
	quit
endif

for(i = Start; i <= End; i++)
	Temp = Path ++ Before ++ i ++ After
	if(file.validpath(Temp)) do
		messagebox("ok error", "Folder " ++ Temp ++ " already exisis", "BatchMD Script")
		quit
	endif
	Str = "/c md " ++ Temp
	file.runwait(0, "cmd", Str, "", "hide")
endfor

win.sendmessage(hwnd, 0x400+51, 540, 0)

Comments:

Как создать множество директорий одним нажатием клавиши? Можно нажать F7 и ввести имена через |, например, dir-a|dir-b|dir-c. Если имена директорий не связаны друг с другом, так и придется поступить. Или написать батник с чем-то вроде for %%a in (dir-a dir-b dir-c) do md %%a.

Данный скрипт позволяет создавать директории, имена которых отличаются только значением целочисленного счетчика, например, Dir-15th, Dir-16th, Dir-17th.

  1. Первый параметр скрипта - текущий путь (всегда "%p");
  2. Второй параметр - текст перед счетчиком ("Dir-" в нашем случае);
  3. Третий параметр - начальное значение счетчика (15);
  4. Четвертый параметр - конечное значение (17);
  5. Пятый параметр - текст после счетчика ("th").

На главную Все о Total Commander PowerPro Все скрипты